フォトショっぽくクリックで変化させてもよかったですが、あまり変化量を上げすぎると画像が荒くなるので、微妙な変化の方が使えるんだと思います。

import flash.display.*;
import flash.filters.*;
import flash.geom.*;

var imgList:String = "image"; // リンケージ画像id

var w:Number = 240;
var h:Number = 360;
var scalex:Number = 0;
var scaley:Number = 0;
var d:Number = 0;

var scalemx:Number = 80; // xscale変化量
var scalemy:Number = 80; // yscale変化量
var r:Number = 60; // フィルタ適用範囲の直径
var speed:Number = 8; // 変化の移動速度

// -- 適用イメージ & マスク作成

var bmp:BitmapData = BitmapData.loadBitmap(imgList);
var copybmp:BitmapData = bmp.clone();

var mc:MovieClip = this.createEmptyMovieClip("img_mc", 2);
var mask:MovieClip = this.createEmptyMovieClip("mask_mc", 3);
var maskbmp:BitmapData = new BitmapData(w, h, false, 0);
mask.attachBitmap(maskbmp, 0);

var mgx:Number = (bmp.width-w)/2;
var mgy:Number = (bmp.height-h)/2;
mc._x -= mgx;
mc._y -= mgy;
mc.attachBitmap(bmp, 0);
mc.setMask(mask);

// -- 置き換えマップ用イメージ作成

var dpmap:BitmapData = new BitmapData(w, w, true, 0);
var dmc:MovieClip = this.createEmptyMovieClip("img_mc", 1);
var mrx:Matrix = new Matrix(1, 0, 0, 1, w/2, w/2);

dmc.beginGradientFill("radial", [0xFFFFFF, 0x808080], [100, 100], [0, r/2], mrx);
dmc.moveTo(0, 0);
dmc.lineTo(w, 0);
dmc.lineTo(w, w);
dmc.lineTo(0, w);
dmc.lineTo(0, 0);
dmc.endFill();

dpmap.draw(dmc);
dmc.removeMovieClip();

// -- フィルタ適用

function onEnterFrame ():Void {
    d += Math.PI/180*speed;
    scalex = Math.cos(d)*scalemx;
    scaley = Math.sin(d)*scalemy;
    var pos:Point = new Point(_xmouse-w/2+mgx, _ymouse-w/2+mgy);
    var dmf:DisplacementMapFilter = 
        new DisplacementMapFilter(dpmap, pos, 1, 1, scalex, scaley, "ignore");
    bmp.applyFilter(copybmp, bmp.rectangle, null, dmf);
}

数値を調整したり他のエフェクトと組み合わせれば、陽炎や磨りガラスなどの効果も可能ですが、モーションをつける場合は、ちょっと大きい描画領域に適用すると重くなってしまうので、なかなか使いどころが難しいです。

ちなみに、DisplacementMapFilterを適用する画像は表示領域よりも少し大きめの画像を用意する必要があります。そうしないと、フィルタを適用した際、アウトラインがはみ出してしまってかっこ悪いのです。

DisplacementMapFilterについては以前のエントリー（ゆらゆら揺れる文字 - DisplacementMapFilter）を参考に。

import flash.display.*;
import flash.filters.*;
import flash.geom.*;

var w:Number = 360;
var h:Number = 240;
var octaves:Number = 3;
var offset:Array = new Array();
var speed:Array = new Array();
var rdm:Number = Math.floor(Math.random()*10000);

// -- MC "image"をステージ上に配置。

var image:MovieClip;
var bmp:BitmapData = new BitmapData(w, h, false, 0);
var mappoint:Point = new Point((image._width-w)/2, (image._height-h)/2);

// -- perlinNoise 移動量設定

for (var i:Number = 0; i < octaves; i++) {
	offset[i] = new Point(Math.random()*w, Math.random()*h);
	speed[i] = new Point(Math.random()*2-1, Math.random()*2-1);
}

// -- エフェクト適用

this.onEnterFrame = function ():Void {
	for(var i:Number = 0; i < octaves; i++){
		offset[i].x += speed[i].x;
		offset[i].y += speed[i].y;
	}
	//  マウス位置によって変化量を調整
	var scalex:Number = (this._xmouse-w/2)/5;
	var scaley:Number = (this._ymouse-h/2)/5;

	bmp.perlinNoise(w/30, h/30, octaves, rdm, false, true, 1, true, offset);
	var dmf:DisplacementMapFilter = 
	new DisplacementMapFilter(bmp, mappoint, 1, 1, scalex, scaley);
	image.filters = [dmf];
}

前回はperlinNoiseでしきい値を計るソースイメージを生成していましたが、今回はあらかじめ用意した画像を読み込む形にしています。これで画像を入れ替えるだけでまったく違った効果ができてしまうわけです。

今回はPhotoshopで作った下の画像を使用。

黒い部分から白い部分にかけて消えていきます。この場合、中心から外側にかけて白を強くしているので、中心からイメージが切り替わるようになります。

ちなみに今回は1回目と2回目でマスク用のソース画像を反転させているため、逆再生になっています。

Transition.as

import flash.display.*;
import flash.filters.*;
import flash.geom.*;

class Transition {
	
	private var W:Number;
	private var H:Number;
	
	private var blur:BlurFilter;
	private var glow:GlowFilter;

	private var src_bmp:BitmapData;
	private var mask1_bmp:BitmapData;
	private var mask2_bmp:BitmapData;
	
	private var image1:MovieClip;
	private var image2:MovieClip;
	private var mc1:MovieClip;
	private var mc2:MovieClip;
	private var gmc:MovieClip;
	private var disp:MovieClip;
	
	function Transition (p:MovieClip, m1:MovieClip, m2:MovieClip, id:String) {
		
		W = m1._width;
		H = m1._height;
		image1 = m1;
		image2 = m2;

		blur = new BlurFilter(1.5, 1.5, 2);
		glow = new GlowFilter(0xFFFFFF, 100, 8, 8, 3, 2, false, true);
		
		src_bmp = BitmapData.loadBitmap(id);
		mask1_bmp = new BitmapData(W, H, true, 0xFFFFFFFF);
		mask2_bmp = new BitmapData(W, H, true, 0xFFFFFFFF);
		
		mc1 = p.createEmptyMovieClip("mc1", 0);
		mc2 = p.createEmptyMovieClip("mc2", 1);
		gmc = p.createEmptyMovieClip("g_mc", 2);
		disp = p.createEmptyMovieClip("d_mc", 3);
		
		mc1.attachBitmap(mask1_bmp, 0);
		mc2.attachBitmap(mask2_bmp, 0);
		gmc.attachBitmap(mask1_bmp, 0);
		
		gmc.blendMode = "overlay";
		gmc.filters = [glow];
		mc1.filters = [blur];
		mc2.filters = [blur];
		
		p.onLoad = function ():Void {
			mc1.cacheAsBitmap = true;
			mc2.cacheAsBitmap = true;
			image1.cacheAsBitmap = true;
			image2.cacheAsBitmap = true;
			image1.setMask(mc1);
			image2.setMask(mc2);
		}
		p.onLoad();
	}
	
	public function changeImage(m:MovieClip):Void {
		
		var mask:BitmapData;
		var m2:MovieClip;
		var thr:Number = 0;
		var b:BitmapData = src_bmp;
		var clr:ColorTransform = new ColorTransform(-1, -1, -1, 1, 255, 255, 255, 0);

		if (m == image1) { 
			mask = mask1_bmp;
			m2 = image2; 
		} else {
			mask = mask2_bmp;
			m2 = image1; 
		}
		gmc.attachBitmap(mask, 0);
		
		m.onEnterFrame = function():Void {
			if (thr > 0xCFFFFF) {
				mask.fillRect(mask.rectangle, 0xFFFFFFFF);
				m.attachBitmap(mask);
				thr = 0x000000;
				m.swapDepths(m2);
				b.colorTransform(b.rectangle, clr);
				delete m.onEnterFrame;
			} else {
				thr += (0xFFFFFF-thr)*0.03;
				mask.threshold(b, b.rectangle, new Point(0, 0), "<=", thr, 0, 0x00FFFFFF , false);
			}
		}
	}
	
}

1フレーム目

// -- ステージ上にMC image1, image2を配置。
// -- 現在のパス、画像MC1、画像MC２、マスク用画像のid （リンケージ設定で書き出しておく）

var ts:Transition = new Transition(this, image1, image2, "imageID");

image1.onRelease = function():Void{
	ts.changeImage(image1);
}

image2.onRelease = function():Void{
	ts.changeImage(image2);
}

今回、焦点がずれるので2つの画像は外部から読み込まずにステージ上にMCを配置しました。画像を外部から読み込む形にする場合、loadClipを使って読み込み処理を終えたことを確認してからsetMaskでマスク処理、という手順が必要なのでご注意を。

import flash.display.*;
import flash.filters.*;
import flash.geom.*;

var w:Number = 360;
var h:Number = 240;
var thr:Number = 0x000000;
var rdm:Number = Math.floor(Math.random()*10000);

// -- image1, image2 はステージ上に配置。 ( image1を上に配置)

var image1:MovieClip;
var image2:MovieClip;

var blur:BlurFilter = new BlurFilter(1.2, 1.2, 2);
var glow:GlowFilter = new GlowFilter(0x4C2E00, 100, 8, 8, 4, 2, true, true);

var bmp:BitmapData = new BitmapData(w+20, h+20, false, 0);
var mask_bmp:BitmapData = new BitmapData(w+20, h+20, true, 0xFFFFFFFF);
var mask2_bmp:BitmapData = new BitmapData(w+20, h+20, true, 0xFFFFFFFF);

var mc:MovieClip = this.createEmptyMovieClip("mc", 0);
var mc2:MovieClip = this.createEmptyMovieClip("mc2", 1);
var gmc:MovieClip = this.createEmptyMovieClip("g_mc", 3);

mc._x = mc._y = -10;
mc2._x = mc2._y = -10;
gmc._x = gmc._y = -10;

mc.attachBitmap(mask_bmp, 0);
mc2.attachBitmap(mask2_bmp, 0);
gmc.attachBitmap(mask_bmp, 0);

gmc.blendMode = "multiply";
gmc.filters = [glow];
mc.filters = [blur];
mc2.filters = [blur];

// -- アルファチャンネルマスクとして使用するため、cacheAsBitmapを有効に。

mc.cacheAsBitmap = true;
mc2.cacheAsBitmap = true;
image1.cacheAsBitmap = true;
image2.cacheAsBitmap = true;

image1.setMask(mc);
image2.setMask(mc2);

// -- トランジッション処理 

function burnImage(mask:BitmapData, m:MovieClip):Function {
	gmc.attachBitmap(mask, 0);
	return function():Void {
		if (thr > 0xCFFFFF) {
			mask.fillRect(mask.rectangle, 0xFFFFFFFF);
			m.attachBitmap(mask);
			thr = 0x000000;
			if (m == image1) { m2 = image2; }
			else { m2 = image1; }
			m.swapDepths(m2);
			delete this.onEnterFrame;
		} else {
			thr += (0xFFFFFF-thr)*0.03;
			mask.threshold(bmp, bmp.rectangle, new Point(0, 0), "<=", thr, 0, 0x00FFFFFF , false);
		}
	}
}

// -- 雲模様画像生成 

function createPerlinNoise():Void {
	rdm = Math.floor(Math.random()*10000);
	bmp.perlinNoise(100, 100, 5, rdm, false, true, 1, true);
}

// -- ボタン処理 

image1.onRelease = function():Void{
	createPerlinNoise();
	this.onEnterFrame = burnImage(mask_bmp, image1);
}

image2.onRelease = function():Void{
	createPerlinNoise();
	this.onEnterFrame = burnImage(mask2_bmp, image2);
}

import flash.filters.*;

var maxi:Number = 16;
var margin:Number = 12;
var w:Number = 360;
var h:Number = 240;
var blur:BlurFilter = new BlurFilter(3, 3, 2);
var dots:MovieClip = this.createEmptyMovieClip("dots_mc", 0);

dots._x = w/2;
dots._y = h/2;
dots.filters = [blur];

for(var i:Number = 1; i < maxi; i++){ 
	var pt:Object = {_x:margin*i-(maxi*margin/2), _y:margin*i-(maxi*margin/2)};
	var mc:MovieClip = dots.attachMovie("dot", "dot"+i, i, pt);
	mc.blendMode = "add";
	mc.gotoAndPlay(i*2);
}

dots.onEnterFrame = function () {
	this._rotation += 2;
}

import flash.filters.*;
import flash.display.*;
import flash.geom.*;

var w:Number = 360;
var h:Number = 240;
var r:Number = 90;
var maxi:Number = 50;
var th_init:Number = 0;
var th:Number = th_init/180*Math.PI;
var bmp:BitmapData = new BitmapData(w, h, true, 0);
var canvas:MovieClip = this.createEmptyMovieClip("canvas", 0);
var bmc:MovieClip;
var clr:ColorTransform = new ColorTransform(.3, .3, .3, .3, -30, 20, 10, 0);

var mat:Matrix = new Matrix(1, 0, 0, 1, w/2, h-40);
var blend:String = "add";
var blur:BlurFilter = new BlurFilter(4, 2, 2);
var maxh:Number = 100;
var minh:Number = 50;

var rate:Number = 1;

var clrmat:ColorMatrixFilter = new ColorMatrixFilter([
		1, 0, 0, 0, 0,
		0, 1, 0, 0, 0,
		0, 0, 1, 0, 0,
		0, 0, 0, .9, 0
		]);
var count:Number = 0;
canvas.attachBitmap(bmp,0);

bmc = this.createEmptyMovieClip("bmc",1);
bmc._x = w/2;
bmc._y = h/2;
bmc._visible = false;
for(var i:Number = 0; i < maxi; i++) {
	var f:MovieClip = bmc.attachMovie("c", "f"+i, i);
	f._yscale = Math.random()*(maxh-minh)+minh;
	f._x = Math.cos(th)*r;
	f._y = Math.sin(th)*r/3;
	f.filters = [blur];
	f.gotoAndPlay (i%f._totalframes);
	th += 360/maxi*(Math.PI/180);
}

this.onEnterFrame = function() :Void {
	if(++count%rate == 0) {
		bmp.draw(bmc, mat, clr, blend, null);
		bmp.applyFilter(bmp, bmp.rectangle, null, blur);
		bmp.applyFilter(bmp, bmp.rectangle, null, clrmat);
	}
}

下図の場合、赤を基準にY方向へ移動させているため、置き換えビットマップの赤の値が中間値（128)より小さいピクセルほど下（正)方向に移動し、赤の値が大きいピクセルほど上（負)方向に変化します。

慣れるまで結構しんどいフィルタですが、よく使う変形のグラデーションパターンを一度作ってしまえば、あとは使いまわすことができます。特に厳密な計算をする必要がない場合は、ステージ上で置き換えマップを作ってしまってもよいかと思います。
以下のサンプルでは、埋め込みフォントを使用する際、必要な文字を埋め込んだダイナミックテキストを別途ステージに配置しておくか、リンケージ設定で書き出しておく必要があります。

import flash.display.*;
import flash.filters.*;
import flash.geom.*;

var w:Number = 360;
var h:Number = 240;

// --- 置き換えマップイメージ作成
var map:BitmapData = new BitmapData(w,h, true ,0);
var mc:MovieClip = this.createEmptyMovieClip("m", 1);
var matrix:Matrix = new Matrix();
matrix.createGradientBox(30, 1, 0, 15, 0);
mc.beginGradientFill("linear", [0xFF0000, 0x0000FF], [100, 100], [34, 220], matrix, "reflect");
mc.moveTo(0, 0);
mc.lineTo(w, 0);
mc.lineTo(w, h);
mc.lineTo(0, h);
mc.lineTo(0, 0);
mc.endFill();

map.draw(mc);
mc.removeMovieClip();

// --- テキスト作成
var txtbox:MovieClip = this.createEmptyMovieClip("txt_mc", 2);
var copytxt:TextField = txtbox.createTextField("copy_txt", 1, 0, 15, 200, 20);
var fmt:TextFormat = new TextFormat();
fmt.font = "フォントを入力";
fmt.size = 20;
copytxt.setNewTextFormat(fmt);
copytxt.embedFonts = true;
copytxt.text = "ゆらゆらゆらゆら";
copytxt.selectable = false;
copytxt.textColor = 0xFFFFFF;
copytxt.autoSize = true;

txtbox._x = (w-txtbox._width)/2;
txtbox._y = (h-txtbox._height)/2;
txtbox.blendMode = "add";

// --- フィルタ 変数
var glow:GlowFilter = new GlowFilter(0x0044CC, 20, 10, 10, 5, 3, false, false);
var blurx:Number = 20; 
var blury:Number = 10;
var alp:Number = 5;

var pos:Point = new Point(-txtbox._width, 0);
var goal:Point = new Point(txtbox._width+240, 0)

// --- フィルタ適用
this.onEnterFrame = function():Void {
	var dmf:DisplacementMapFilter = new DisplacementMapFilter(map, pos, 1, 1, 10, 25, "clamp");
	var blur:BlurFilter = new BlurFilter(blurx, blury, 3);
	var matrix:Array = [
		1, 1, .5, 0, 1, 
		1, 1, .5, 0, 1, 
		2, .5, 1, 0, 1, 
		0, 0, 0, alp, 0
		];
	var clrmrx:ColorMatrixFilter = new ColorMatrixFilter(matrix);
	txtbox.filters = [dmf, glow, blur, clrmrx];
	if(Math.abs(pos.x-goal.x) <= 120){
		pos.x = -txtbox._width;
		blurx = 20;
		blury = 10;
		alp = 5;
	}
	pos.x += (goal.x-pos.x)*0.01;
	blurx += -blurx*0.035;
	blury += -blury*0.035;
	alp += (1-alp)*0.07;
}

サンプルでは、matrix.scaleで拡大させていますが、左上を基準に拡大されるため、このままだと中心がズレてしまうので、matrix.translateで移動量だけ中心に戻しています。カラーはタイムラインで変化させて、フレームに飛ばしてます。

import flash.display.*;
import flash.geom.*;
import flash.filters.*;

var scale:Number = 1.24;
var blur:BlurFilter = new BlurFilter(1, 1, 2);
var dep:Number = 0;

this.createEmptyMovieClip("src_mc",1);
this.createEmptyMovieClip("cap_mc",2);

var src:BitmapData = new BitmapData(360, 240, true, 0);
var cap:BitmapData = src.clone(); 
src_mc.attachBitmap(src, 1);
 
var matrix:Matrix = new Matrix();
var clr:ColorTransform = new ColorTransform();

matrix.scale(scale, scale); 
matrix.translate((cap.width-cap.width*scale)/2, (cap.height-cap.height*scale)/2);

this.onEnterFrame = function():Void {
	createParticle();
	cap.draw(this);
	cap.applyFilter(cap, cap.rectangle, new Point(0,0), blur);
	src.draw(cap, matrix, clr, "normal", src.rectangle, true);
}

function createParticle():Void {
	dep++;
	var part:MovieClip = cap_mc.attachMovie("star", "star_mc" + dep, dep);
	part.blendMode = "hardlight";
	part._x = cap_mc._xmouse;
	part._y = cap_mc._ymouse;
	part.gotoAndPlay(Math.floor(dep%part._totalframes)+1);
	part._xscale = part._yscale = 25 + 75*Math.random();
	part.vx = (Math.random()*2-1)*10;
	part.vy = (Math.random()*2-1)*10;
	part.onEnterFrame = scatter;
}

function scatter():Void {
	this._x += this.vx *= .9;
	this._y += this.vy *= .9;
	this._xscale = this._yscale *= .9;
	if (this._xscale < 10){
		this.removeMovieClip();
	}
}